Indicadores

22 feb 2016 - Txema Medina

Centro de Gravedad - Indicador de Tendencia

Este indicador que acompaña al precio nos puede proporcionar la información necesaria para entrar a mercado cuando se inicia una tendencia, bien al alza o la baja. Para entrar con el inicio de la tendencia, línea gruesa azul o roja, tenemos que tener en cuenta la serie de velas en ese momento.

Con velas Heiken Ashi podemos esperar a que las velas sean verdes y nos acompañen en la subida si entramos al alza. De esta forma evitamos el retroceso que se produjo desde el 18 al 29 sep 2015 mientras el indicador CG nos marcaba inicio de tendencia.

Durante la duración de la tendencia, indicada por la línea central roja o azul en el interior de las bandas, se producen retrocesos o rebotes que llevan al precio hacia las bandas inferiores o superiores. Esto lo podemos ver en el tramo bajista desde el 20 de dic 2015 hasta el 16 feb 2016 los indicadores Vigia 10 y Koncorde 10 (Blai5) nos indican estos pequeños rebotes que no invalidan la tendencia bajista marcada por el indicador Centro de Gravedad.

Hoy 22 feb 2016 ya tenemos el indicador con su color azul y su alerta inferior con color verde que nos señalan inicio de un tramo alcista. Las velas Heiken Ashi desde el 16 feb son verdes y precisamente el precio ha roto el nivel de 1.930 al alza con gap alcista. Creo que se puede intentar una entrada sobre estos niveles con un stop-loss no inferior a 1.822.

NOTA: Debemos tener en cuenta que la media central, la base del indicador, es una media dinámica por lo que varía con los precios y hace que los colores azul y rojo retrocedan cuando hay un cambio de tendencia simulando que el cambio de tendencia se ha producido con antelación.

Para acceder al indicador solamente tenéis que pasar por la web de Miguel Angel Castillo, el mago de los indicadores para PRT: http://bolsatrilera.blogspot.com.es/2014/02/analista-de-la-semana.html
http://bolsatrilera.blogspot.com.es/2013/07/santander.html (entre los comentarios)
Página del autor: http://www.belkhayatelab.com/
Estrategias con el indicador CG: http://www.belkhayatelab.com/en/belkhayate-gc/gravity-center.html

Semáforo SMI-STK Momentum Index

Txema Medina - 14 noviembre 2013
Os presento un indicador que nos puede ayudar a la hora de decidirnos a realizar una entrada en el mercado. Por supuesto el timing del mercado debe ser favorable con los índices en clara tendencia alcista. Pero los recortes del mercado nos pueden dar buenas oportunidades para reincorporarnos a la tendencia general. Y aquí es donde necesitamos una pequeña ayuda para elegir bien los valores de entre los que pertenecen a sectores fuertes.
Tomando como base el Indicador SMI-Stochastic Momentum Index he creado este semáforo o alerta que nos dará señales visuales del comportamiento de los valores. Para ello disponemos de barras naranjas, verdes y rojas. Las naranjas nos avisan de un posible rebote, las verdes confirman la entrada y la roja nos avisa de que hay que ajustar los stops o salir directamente con los beneficios.
Los cruces al alza en el SMI por debajo de 40 nos proporcionan señales de entrada en el mercado y los cruces a la baja por encima de 80 nos avisan del deterioro de los precios. Este indicador puede ser sustituido por el clásico Estocástico (10,3,5).
Para evitar señales en los rebotes de las correcciones significativas he empleado un filtro de medias exponenciales, 13 y 39, de tal modo que se exige que como mínimo alguna de ellas sea alcista.
Como siempre estas señales necesitan ser contrastadas con otras que podemos obtener del Macd, Mano Fuerte, RSCMansfield, CCI, Vigia, Gatillo, ... 
Espero que os sirva para vuestra operativa y si teneis alguna propuesta de mejora encantado de recibirla.
Información sobre el Indicador SMI: http://esbolsa.com/blog/analisis-tecnico/smi-stochastic-momentum-index/
Saludos de Txema

REM SEMAFORO SMI-STK Momentum Index
REM CREADO POR TXEMA MEDINA EN OCT 2013
REM LAS BARRAS NARANJAS INDICAN PREPARADOS PARA POSIBLE ENTRADA DE LARGOS
REM LAS BARRAS VERDES CONFIRMAN LAS ENTRADAS DE LARGOS
REM LAS BARRAS ROJAS INDICAN CIERRE DE LARGOS
REM LAS BARRAS NARANJAS Y ROJAS DESPUES DE VARIAS BARRAS VERDES NOS ALERTAN DE UNA CORRECCION. DEPENDIENDO DE LA
REM RAPIDEZ EN NUESTRA OPERATIVA PODEMOS CERRAR POSICIONES O AJUSTAR STOPS A LOS MINIMOS RELATIVOS ANTERIORES.

mySMI = SMI[19,3,3](close)
MediaSMI = Average[13](SMI[19,3,3](close))

REM REBOTE LARGOS = SMI ASCENDIENDO POR DEBAJO DE 40 Y MEDIAS DEL FILTRO BAJISTAS
ReboteLargos = mySMI < 40 AND mySMI > mySMI[1]
REM SEÑAL LARGOS = SMI CRUZANDO SU MEDIA POR DEBAJO DE 40 O SMI POR ENCIMA DEL NIVEL 40
SenialLargos = ((mySMI < 40 AND mySMI >= MediaSMI) OR mySMI >= 40) AND mySMI > mySMI[1]
REM ENTRADA LARGOS = SMI > MEDIA POR DEBAJO DE CERO O SMI POR ENCIMA DE LA MEDIA
EntradaLargos = (mySMI < 0 AND mySMI >= mediaSMI) OR mySMI > mediaSMI
REM CIERRE LARGOS = EL SMI CRUZA LA MEDIA A LA BAJA POR ENCIMA DE CERO
CierreLargos = mySMI > 0 AND mySMI CROSSES UNDER mediaSMI

REM FILTRO PARA NO OPERAR EN LOS REBOTES DE LAS CORRECCIONES = EMM13 Y EMM39 ALCISTAS
mm13 = ExponentialAverage[13](close)
mm39 = ExponentialAverage[39](close)
FILTRO = mm13 > mm13[1] OR mm39 > mm39[1]

CERO = 0

IF REBOTELARGOS THEN
SEMAFORO1 = 1
ELSE
SEMAFORO1 = 0
ENDIF
IF SENIALLARGOS AND FILTRO THEN
SEMAFORO2 = 2
ELSE
SEMAFORO2 = 0
ENDIF
IF ENTRADALARGOS AND FILTRO THEN
SEMAFORO3 = 3
ELSE
SEMAFORO3 = 0
ENDIF
IF CIERRELARGOS THEN
SEMAFORO4 = 3
ELSE
SEMAFORO4 = 0
ENDIF

RETURN SEMAFORO4 COLOURED(255,0,0) AS "Cierre", SEMAFORO3 COLOURED (51,153,0) AS "Entrada", SEMAFORO2 COLOURED (51,255,51) AS "SenialEntrada", SEMAFORO1 COLOURED (255,153,0) AS "ReboteLargos", Cero as "0"
___________________________________________________________________________
Alerta Alligator AO
Txema Medina - 20 mayo 2013
Os presento un nuevo indicador en forma de alerta para Pro Real Time. Se trata del indicador Accelerator Oscilator, Oscilador de Aceleracion/Desaceleración o Alligator AO, que es como aparece en PRT.

Este indicador nos permite realizar entradas en activos justo cuando la fuerza de la tendencia en curso disminuye y comienza un nuevo impulso. Tiene la habilidad de adelantarse al movimiento posterior del precio por lo que nos da un margen de ventaja que podemos aprovechar cuando aparecen 2 barras verdes por debajo de cero si han estado precedidas de barras rojas o naranjas. Esto para entrar largos, y para cortos a la inversa.

_____________________________________________________________________________________

REM ALERTA ALLIGATOR AO
REM CREADO POR TXEMA MEDINA EN MAYO 2013
REM http://labolsamemata.blogspot.com.es/2013/05/alerta-alligator-ao.html
REM SE HAN MODIFICADO LOS NOMBRES DEL INDICADOR ALLIGATOR AO:
//ChaosAO=Average[5](MedianPrice)-Average[34](MedianPrice)
//ChaosAOSignalLine=Average[5](ChaosAO)
//ChaosAC=ChaosAO-Average[5](ChaosAO)
REM ENTRADA LARGOS: 2 BARRAS VERDES POR DEBAJO DE CERO - 3 BARRAS VERDES = CONFIRMA LA ENTRADA
REM ENTRADA CORTOS:2 BARRAS ROJAS POR ENCIMA DE CERO - 3 BARRAS ROJAS = CONFIRMA LA ENTRADA
REM PARA LA CREACION DEL INDICADOR SE HA UTILIZADO LA ESTRUCTURA DEL INDICADOR BULL/ BEAR DE MIGUEL LARRAÑAGA - www.markettiming.info

FuerzaAO = (Average[5](MedianPrice)/(MedianPrice)-Average[34](MedianPrice)/(MedianPrice))*100
MediaFuerzaAO = Average[5](FuerzaAO)
AceleracionAO = FuerzaAO-Average[5](FuerzaAO)

Largos1 = (FuerzaAO > FuerzaAO[1])
Cortos1 = (FuerzaAO < FuerzaAO[1])
Largos2 = (Largos1 and FuerzaAO > MediaFuerzaAO and AceleracionAO > AceleracionAO[1])
Cortos2 = (Cortos1 and FuerzaAO < MediaFuerzaAO and AceleracionAO < AceleracionAO[1])

if Largos1 then
alerta1 = fuerzaAO
else
alerta1 = 0
endif

if Cortos1 then
alerta2 = fuerzaAO
else
alerta2 = 0
endif

if Largos2 then
alerta3 = fuerzaAO
else
alerta3 = 0
endif

if Cortos2 then
alerta4 = fuerzaAO
else
alerta4 = 0
endif

RETURN alerta1 coloured (51,255,51) as "Largos1", alerta2 coloured (255,153,0) as "Cortos1", alerta3 coloured (51,153,0) as "Largos2", alerta4 coloured (255,0,0) as "Cortos2"

______________________________________________________________________________________________

Indicador Alerta Gatillo 7.0
Txema Medina - 18 marzo 2013 Os presento el indicador Alerta Gatillo 7.0 con las últimas modificaciones realizadas. Creo que ya está completo. Está basado en el indicador Gatillo 7.0 de Miguel Larrañaga. Recordaros que Gatillo 7.0 está basado en el indicador Vigía 09 de Blai5-Xavier García (Bolsa&Datos.com - Bali5.net).
Solamente hay que configurarlo como histograma ya que lleva los colores por defecto en la programación. Si al copiar y pegar os da problemas, borrar las comillas de la última línea, RETURN..., y volver a escribirlas.
Os pego un gráfico para comprobar que se sincroniza perfectamente con los indicadores Arco Iris 9.999 y  Semáforo Alcista.
Que lo disfrutéis y que le saquéis todo el potencial que tiene, que bajo mi punto de vista es mucho, y más combinado con los indicadores indicados anteriormente. Acceder a la imágen>>>


-----------------------------------------------------------------------------------------
BARRA VERDE CLARO: ALERTA DE COMPRA Y POSIBLE REBOTE
VIGIA POR ENCIMA DE GATILLO Y GATILLO < 0

BARRA VERDE OSCURO: CONFIRMACION DE COMPRA
VIGIA POR ENCIMA DE GATILLO Y GATILLO > 0

BARRA NARANJA: POSIBLE VENTA
VIGIA POR DEBAJO DE GATILLO Y GATILLO > 0

BARRA ROJA: VENTA
VIGIA POR DEBAJO DE GATILLO
----------------------------------------------------------------------------------------

REM CREADO POR TXEMA MEDINA EN MARZO 2013 - http://labolsamemata.blogspot.com
REM BASADO EN EL INDICADOR GATILLO 7.0 DE MIGUEL LARRAÑAGA - www.markettiming.info

alerta = 0
ignored, ignored, ignored, ignored, ignored, vigia, gatillo, ignored = CALL "Gatillo 7.0"

REM CONDICIONES DE COMPRA Y VENTA
if (vigia crosses over gatillo or vigia > gatillo) and gatillo < 0 then
alerta = 0.5
elsif (vigia crosses over gatillo or vigia > gatillo) and gatillo > 0 then
alerta = 1
elsif  vigia crosses under gatillo or vigia < gatillo and gatillo > 0  then
alerta = -0.5
elsif  vigia crosses under gatillo or vigia < gatillo  then
alerta = -1
else
alerta = 0
endif

barraAlcista1 = 0
barraAlcista2 = 0
barraBajista1 = 0
barraBajista2 = 0

IF alerta = 0.5 THEN
barraAlcista1 = 1
barraAlcista2 = 0
barraBajista1 = 0
barraBajista2 = 0
ELSIF alerta = 1 THEN
barraAlcista1 = 0
barraAlcista2 = 1
barraBajista1 = 0
barraBajista2 = 0
ELSIF alerta = -0.5 THEN
barraAlcista1 = 0
barraAlcista2 = 0
barraBajista1 = 1
barraBajista2 = 0
ELSIF alerta = -1 THEN
barraAlcista1 = 0
barraAlcista2 = 0
barraBajista1 = 0
barraBajista2 = 1
ENDIF

RETURN barraAlcista1 COLOURED(0,255,0) As "alcista1", barraAlcista2 COLOURED(0,102,0) As "alcista2", barraBajista1 COLOURED(255,153,0) As "bajista1", barraBajista2 COLOURED(255,0,0) As "bajista2"

____________________________________________________________________________________________________________
Indicador Alerta ADX v.1
Txema Medina - 18 abril 2013
Hoy os presento el Indicador para PRT ALERTA ADX v.1 basado en el Indicador Movimiento Direccional ADX de J. Welles Wilder. Como ya sabeis está formado por 3 líneas, línea ADX, linea +DI de movimiento positivo y línea -DI de movimiento negativo.
El Indicador ADX mide la fuerza de la tendencia ya sea alcista o bajista, expresada por medio de su línea principal ADX. Por encima de 25 se considera que el valor está en tendencia. Si supera el nivel 30 se considera que la tendencia es fuerte y gráficamente se observa por tener una pendiente positiva. A partir del nivel 50 podemos considerar que el valor entra en zona de saturación o posible techo de mercado, y por tanto susceptible de revertirse la tendencia. Por debajo del nivel 25 se considera que el valor está sin tendencia o en un rango lateral, por lo que se aconseja no operar hasta que lo supere.

Las líneas +DI y -DI acompañan a la tendencia de manera que en tendencia alcista la línea +DI se sitúa por encima de la línea -DI y en tendencia bajista al revés.
A la hora de operar los cruces de las líneas +DI y -DI nos ofrecen puntos de entrada en la dirección que marquen estas líneas siempre que la línea ADX esté por encima del nivel 25.

En la programación del indicador he utilizado una ADX con valor 9 y valor 14 para las líneas +DI y -DI.
Para tener toda la información necesaria sobre el Indicador Movimiento Direccional ADX os dejo este enlace: http://www.bolsalibre.es/articles/view/adx-average-direction-index

 ________________________________________________________________________________________

REM CREADO POR TXEMA MEDINA EN ABRIL 2013
REM http://labolsamemata.blogspot.com.es/2013/04/indicador-alerta-adx-v1.html
REM CONDICIONES DEL INDICADOR:
REM INICIO DE LA TENDENCIA = ADX MAYOR DE 23
REM CONFIRMACION DE LA TENDENCIA = ADX MAYOR DE 30
REM SIN TENDENCIA O LATERAL = ADX MENOR DE 23
REM SATURACION = POSIBLE TECHO DE MERCADO = MAYOR DE 50
REM COMBINADO CON EL INDICADOR BULL/BEAR Y ALERTA GATILLO 7.0 SE PRODUCEN SEÑALES POTENTES

myADX = ADX[9]
myDIplus = DIplus[14](close)
myDIminus = DIminus[14](close)

Largos1 = myADX > 23.0 and myADX < 30.0 and myDIplus > myDIminus
Largos2 = myADX > 30.0 and myDIplus > myDIminus
Saturacion = myADX > 50.0
Esperar = myADX < 23.0
Cortos1 = myaDX > 23.0 and myADX < 30.0 and myDIminus > myDIplus
Cortos2 = myADX > 30.0 and myDIminus > myDIplus

cero = 0
IF Largos1 then
BarraLargos1 = 1
ELSE
BarraLargos1 = 0
ENDIF

IF Largos2 then
BarraLargos2 = 1
ELSE
BarraLargos2 = 0
ENDIF

IF Saturacion then
BarraSaturacion = 1
ELSE
BarraSaturacion = 0
ENDIF

IF Esperar then
BarraEsperar = 1
ELSE
BarraEsperar = 0
ENDIF

IF Cortos1 then
BarraCortos1 = 0.5
ELSE
BarraCortos1 = 0
ENDIF

IF Cortos2 then
BarraCortos2 = 1
ELSE
BarraCortos2 = 0
ENDIF

RETURN BarraLargos1 COLOURED (0,255,0) as "Largos1", BarraLargos2 COLOURED (51,153,0) as "Largos2", BarraSaturacion COLOURED (255,55,255) as "Saturacion", BarraEsperar COLOURED (255,153,0) as "Esperar", BarraCortos1 COLOURED (255,0,0) as "Cortos1", BarraCortos2 COLOURED (255,0,0) as "Cortos2", cero as "cero"